While working with a large amount of data in Excel, itâ€™s very common to use INDEX-MATCH functions to lookup parameters under multiple criteria for sum or other related applications. In this article, youâ€™ll get to know how you can incorporate SUM, SUMPRODUCT, SUMIF, or SUMIFS functions along with the INDEX-MATCH formula to sum or evaluate summation under numerous criteria in Excel.

**Read more:** INDEX MATCH Multiple Criteria in Excel

The above screenshot is an overview of the article which represents a dataset & an example of how you can evaluate sum in Excel under different conditions along with columns & rows. Youâ€™ll learn more about the dataset and all suitable functions in the following methods in this article.

**Table of Contents**hide

**Download Practice Workbook**

You can download the Excel workbook that weâ€™ve used to prepare this article.

**Introduction to the Functions: SUM, INDEX and MATCH with Examples**

Before getting down to how these three functions work combinedly, letâ€™s get introduced to these functions & their working process one by one.

**1. SUM**

**Objective:**

**Sums all the numbers in a range of cells.**

**Formula Syntax:**

**=SUM(number1, [number2],â€¦)**

**Example:**

In our dataset, a list of computer devices of different brands is present along with the selling prices of 6 months for a computer shop.

We want to know the total selling price of the desktops of all brands for January only.

**ðŸ“Œ**** Steps:**

âž¤ In** Cell F18**, we have to type:

`=SUM((C5:C14=F16)*D5:D14)`

âž¤ Press **Enter** & youâ€™ll see the total selling price of all desktops for January at once.

Inside the **SUM** function, there lies only one array. Here, **C5:C14=F16** means weâ€™re instructing the function to match criteria from **Cell F16** in the range of cells **C5:C14**. By adding another range of cells **D5:D14** with an **Asterisk(*)** before, weâ€™re telling the function to sum up all the values from that range under the given criteria.

**2. INDEX**

**Objective:**

**Returns a value of reference of the cell at the intersection of the particular row and column, in a given range.**

**Formula Syntax:**

**=INDEX(array, row_num, [column_num])**

**or,Â **

**=INDEX(reference, row_num, [column_num], [area_num])**

**Example:**

Assuming that we want to know the value at the intersection of the 3rd row & 4th column from the array of selling prices from the table.

**ðŸ“Œ**** Steps:**

âž¤ In **Cell F19**, type:

`=INDEX(D5:I14,3,4)`

âž¤ Press **Enter** & youâ€™ll get the result.

Since the 4th column in the array represents the selling prices of all devices for April & the 3rd row represents the Lenovo Desktop category, so at their intersection in the array, weâ€™ll find the selling price of Lenovo Desktop in April.

**3. MATCH**

**Objective:**

**Returns the relative position of an item in an array that matches a specified value in a specified order.**

**Formula Syntax:**

**=MATCH(lookup_value, lookup_array, [match_type])**

**Example:**

First of all, weâ€™re going to know the position of the month June from the month headers.

**ðŸ“Œ**** Steps:**

âž¤ In **Cell F17**, our formula will be:

`=MATCH(F16,D4:I4,0)`

âž¤ Press **Enter **& youâ€™ll find that the column position of the month June is 6 in the month headers.

Change the name of the month in **Cell F17 **& youâ€™ll see the related column position of another month selected.

And if we want to know the row position of the brand Dell from the names of the brands in **Column B**, then the formula in **Cell F20** will be:

`=MATCH(F19,B5:B14,0)`

Here, **B5:B14** is the range of cells where the name of the brand will be looked for. If you change the brand name in **Cell F19**, youâ€™ll get the related row position of that brand from the selected range of cells.

**Use of INDEX and MATCH Functions Together in Excel**

Now weâ€™ll know how to use **INDEX & MATCH** functions together as a function and what exactly this combined function returns as output. This combined **INDEX-MATCH** function is effective to find specific data from a large array. **MATCH **function here looks for the row & column positions of the input values & the **INDEX** function will simply return the output from the intersection of that row & column positions.

**Read more:** Index Match Multiple Criteria in Rows and Columns in Excel

Now, based on our dataset, we want to know the total selling price of the Lenovo brand in June.

**ðŸ“Œ**** Steps:**

âž¤ In **Cell E19**, type:

`=INDEX(D5:I14,MATCH(E17,B5:B14,0),MATCH(E16,D4:I4,0))`

âž¤ Press** Enter **& youâ€™ll find the result instantly.

If you change the month & device name in **E16 & E17** respectively, youâ€™ll get the related result in **E19** at once.

**Nesting INDEX and MATCH Functions inside the SUM Function**

Hereâ€™s the core part of the article based on the uses of **SUM** or **SUMPRODUCT, INDEX & MATCH** functions together. We can find the output data under 10 different criteria by using this compound function. Here, the **SUM** function will be used for all of our criteria but you can replace it with the **SUMPRODUCT** function too & the results will be unchanged.

**Criteria 1: Finding Output Based on 1 Row & 1 Column with SUM, INDEX and MATCH Functions Together**

Based on our 1st criterion, we want to know the total selling price of the Acer brand in April.

**ðŸ“Œ**** Steps:**

âž¤ In **Cell F20**, the formula will be:

`=SUM(INDEX(D5:I14,MATCH(F18,B5:B14,0),MATCH(F19,D4:I4,0)))`

âž¤ Press **Enter **& the return value will be $ 3,250.00.

**Criteria 2: Extracting Data Based on 1 Row & 2 Columns with SUM, INDEX and MATCH Functions Together**

Now we want to know the total selling price of HP devices in the months of February as well as June.

**ðŸ“Œ**** Steps:**

âž¤ In **Cell F21**, we have to type:

`=SUM(INDEX(D5:I14,MATCH(F18,B5:B14,0),MATCH({"Feb","Jun"},D4:I4,0)))`

âž¤ After pressing **Enter**, youâ€™ll find the resultant value as $ 21,990.00.

Here, in the second **MATCH** function, weâ€™re defining the months within curly brackets. Itâ€™ll return the column positions of both of the months.** INDEX** function then searches for the selling prices based on the intersections of rows & columns and finally **SUM** function will add them up.

**Criteria 3: Determining Values Based on 1 Row & All Columns with SUM, INDEX and MATCH Functions Together**

In this part, weâ€™ll deal with all columns with 1 fixed row. So, we can find the total selling price of Lenovo devices in all months under our criteria here.

**ðŸ“Œ**** Steps:**

âž¤ In **Cell F20**, type:

`=SUM(INDEX(D5:I14,MATCH(F18,B5:B14,0),0))`

âž¤ Press **Enter **& youâ€™ll find the total selling price as $ 36,830.00.

In this function, to add criteria for considering all months or all columns, we have to type **0** as the argument- **column_pos** inside the **MATCH** function.

**Criteria 4: Calculating Sum Based on 2 Rows & 1 Column with SUM, INDEX and MATCH Functions Together**

In this section under 2 rows & 1 column criteria, weâ€™ll find out the total selling price of HP & Lenovo devices in June.

**ðŸ“Œ**** Steps:**

âž¤ In **Cell F21**, the formula will be under the given criteria:

`=SUM(INDEX(D5:I14,MATCH({"HP","Lenovo"},B5:B14,0),MATCH(F20,D4:I4,0)))`

âž¤ After pressing** Enter**, weâ€™ll find the return value as $ 16,680.

Here inside the first **MATCH** function, we have to input HP & Lenovo inside an array by enclosing them with curly braces.

**Criteria 5: Evaluating Sum Based on 2 Rows & 2 Columns with SUM, INDEX and MATCH Functions Together**

Now weâ€™ll consider 2 rows & 2 columns to extract the total selling prices of HP & Lenovo devices for two particular months- April & June.

**ðŸ“Œ**** Steps:**

âž¤ Type in **Cell F22**:

`=SUM(INDEX(D5:I14,MATCH({"HP","Lenovo"},B5:B14,0),MATCH(F20,D4:I4,0)))+SUM(INDEX(D5:I14,MATCH({"HP","Lenovo"},B5:B14,0),MATCH(F21,D4:I4,0)))`

âž¤ Press** Enter** & youâ€™ll see the output as $ 25,980.00.

What weâ€™re doing here is incorporating two **SUM **functions by adding a** Plus(+) **between them for two different months.

**Criteria 6: Finding out Result Based on 2 Rows & All Columns with SUM, INDEX and MATCH Functions Together**

In this part, letâ€™s deal with 2 rows & all columns. So weâ€™ll find out the total selling prices for HP & Lenovo devices in all months.

**ðŸ“Œ**** Steps:**

âž¤ Our formula will be in **Cell F21:**

`=SUM(INDEX(D5:I14,MATCH(F18,B5:B14,0),0))+SUM(INDEX(D5:I14,MATCH(F19,B5:B14,0),0))`

âž¤ Press **Enter** & weâ€™ll find the resultant value as $ 89,870.

**Criteria 7: Determining Output Based on All Rows & 1 Column with SUM, INDEX and MATCH Functions Together**

Under this criterion, we can now extract the total selling prices of all devices for a single month (March).

**ðŸ“Œ**** Steps:**

âž¤ Insert the formula in **Cell F20**:

`=SUM(INDEX(D5:I14,0,MATCH(F19,D4:I4,0)))`

âž¤ Press **Enter** & youâ€™re done. The return value will be $ 141,230.00.

**Criteria 8: Extracting Values Based on All Rows & 2 Columns with SUM, INDEX and MATCH Functions Together**

In this part, weâ€™ll determine the total selling price of all devices for two months- February & June.

**ðŸ“Œ**** Steps:**

âž¤ In **Cell F21**, we have to type:

`=SUM(INDEX(D5:I14,0,MATCH(F19,D4:I4,0)))+SUM(INDEX(D5:I14,0,MATCH(F20,D4:I4,0)))`

âž¤ After pressing **Enter**, the total selling price will appear as $ 263,140.00.

**Criteria 9: Finding Result Based on All Rows & All Columns with SUM, INDEX and MATCH Functions Together**

Weâ€™ll now find out the total selling price of all devices for all months in the table.

**ðŸ“Œ**** Steps:**

âž¤ In **Cell F20**, you have to type:

`=SUM(INDEX(D5:I14,0,0))`

âž¤ Press **Enter** & youâ€™ll get the resultant value as $ 808,090.00.

You donâ€™t need to use **MATCH** functions here as weâ€™re defining all columns & row positions by typing 0â€™s inside the **INDEX **function.

**Criteria 10: Calculating Sum Based on Distinct Pairs with SUM, INDEX and MATCH Functions Together**

In our final criterion, weâ€™ll find out the total selling prices of HP devices for April along with Lenovo devices for June together.

**ðŸ“Œ**** Steps:**

âž¤ Under this criterion, our formula in **Cell F22** will be:

`=SUM(INDEX(D5:I14,MATCH({"HP","Lenovo"},B5:B14,0),MATCH({"Apr","Jun"},D4:I4,0)))`

âž¤ Now press **Enter** & youâ€™ll see the result as $ 12,730.00.

While adding distinct pairs in this combined function, we have to insert the device & month names inside the two arrays based on the arguments for row & column positions and the device & month names from the pairs must be maintained in corresponding order.

**Use of SUMIF with INDEX-MATCH Functions to Sum under Multiple Criteria**

Before getting down to the uses of another combined formula, letâ€™s get introduced to the **SUMIF** function now.

**Formula Objective:**

**Add the cells specified by the given conditions or criteria.**

**Formula Syntax:**

**=SUMIF(range, criteria, [sum_range])**

**Arguments:**

**range- **Range of cells where the criteria lie.

**criteria- **Selected criteria for the range.

**sum_range- **Range of cells that are considered for summing up.

**Example:**

Weâ€™ll use our previous dataset here to keep the flow. With the SUMIF function, weâ€™ll find the total sales in May for desktops only of all brands. So, our formula in **Cell F18** will be:

`=SUMIF(C5:C14,F17,H5:H14)`

After pressing **Enter**, youâ€™ll get the total sales price as $ 71,810.

Letâ€™s use **SUMIF** with** INDEX & MATCH** functions to sum under multiple criteria along with columns & rows. Our dataset is now a bit modified. In **Column A**, 5 brands are now present with multiple appearances for their 2 types of devices. Sales prices in the rest of the columns are unchanged.

Weâ€™ll find out the total sales of Lenovo devices in June.

**ðŸ“Œ**** Steps:**

âž¤ In the output **Cell F18**, the related formula will be:

`=SUMIF(B5:B14,F17,INDEX(D5:I14,0,MATCH(F16,D4:I4,0)))`

âž¤ Press **Enter** & youâ€™ll get the total sales price for Lenovo in June at once.

And if you want to switch to the device category, assuming you want to find the total sales price for the desktop then our **Sum Range** will be **C5:C14** & **Sum Criteria** will be Desktop now. So, in that case, the formula will be:

`=SUMIF(C5:C14,F17,INDEX(D5:I14,0,MATCH(F16,D4:I4,0)))`

**Use of SUMIFS with INDEX & MATCH Functions in Excel**

**SUMIFS** is the subcategory of the **SUMIF** function. Using the SUMIFS function and **INDEX & MATCH** functions inside, you can add more than 1 criterion that is not possible with the **SUMIF** function. In **SUMIFS** functions, you have to input the **Sum Range** first, then **Criteria Range**, as well as Range Criteria, will be placed. Now based on our dataset, weâ€™ll find out the sales price of the Acer desktop in May. Along the rows, weâ€™re adding two different criteria here from **Columns B & C**.

**ðŸ“Œ**** Steps:**

âž¤ The related formula in **Cell F19** will be:

`=SUMIFS(INDEX(D5:I14,0,MATCH(F16,D4:I4,0)),B5:B14,F17,C5:C14,F18)`

âž¤ Press **Enter** & the function will return as $ 9,000.00.

**Concluding Words**

I hope all of these methods mentioned above will now prompt you to apply them in your regular Excel chores. If you have any questions or feedback, please let me know through your valuable comments. Or you can have a glance at our other interesting & informative articles on this website.

**You May Also Like to Explore**

- INDEX, MATCH and MAX with Multiple Criteria in Excel
- INDEX-MATCH Formula to Find Minimum Value in Excel
- SUMPRODUCT with INDEX and MATCH Functions in Excel
- Index Match Sum Multiple Rows
- How to Use INDEX MATCH with Multiple Criteria in a Different Sheet (2 Ways)
- INDEX MATCH across Multiple Sheets in Excel (With Alternative)
- INDEX MATCH with 3 Criteria in Excel (4 Examples)
- How to use INDEX & MATCH worksheet functions in Excel VBA

I recreated the table/data you are using as your example but while attempting to use “Use of SUMIFS with INDEX & MATCH Functions in Excel” formula (=SUMIFS(INDEX(D5:I14,0,MATCH(F16,D4:I4,0)),B5:B14,F17,C5:C14,F18)), it keeps returning a “#N/A” with the message, “Error Argument must be a range.”

Any idea where I’m going wrong?

The formula is working at our end perfectly. You can download the workbook where we did the whole thing and cross-check, please.